homelab-nomad/services/photoprism.tf

module "photoprism_module" {
  source = "./service"

  name               = "photoprism"
  image              = "photoprism/photoprism:231128"
  image_pull_timeout = "10m"
  # constraints = [{
  #   attribute = "$${meta.hw_transcode.type}"
  #   # operator = "is_set"
  #   value = "raspberry"
  # }]
  priority = 60

  # docker_devices = [{
  #   host_path      = "$${meta.hw_transcode.device}"
  #   container_path = "$${meta.hw_transcode.device}"
  # }]
  resources = {
    cpu        = 1500
    memory     = 2200
    memory_max = 4000
  }
  sticky_disk = true
  host_volumes = [
    {
      name      = "photoprism-storage"
      dest      = "/photoprism-storage"
      read_only = false
    },
    {
      name      = "photoprism-media"
      dest      = "/photoprism-media"
      read_only = false
    },
  ]

  ingress      = true
  service_port = 2342
  use_wesher   = var.use_wesher
  ingress_middlewares = [
    "authelia@nomad"
  ]

  mysql_bootstrap = {
    enabled = true
  }

  env = {
    PHOTOPRISM_DEBUG = true
    # Make public since we added Authelia at the proxy level
    PHOTOPRISM_AUTH_MODE = "public"
    # UI
    PHOTOPRISM_SITE_CAPTION     = "AI-Powered Photos App"
    PHOTOPRISM_SITE_DESCRIPTION = "Fijolek home photos"
    PHOTOPRISM_SITE_TITLE       = "PhotoPrism"
    PHOTOPRISM_SITE_URL         = "https://photoprism.${var.base_hostname}/"
    PHOTOPRISM_SPONSOR          = "true"
    # Worker config
    PHOTOPRISM_WORKERS = 2
    # Paths
    PHOTOPRISM_ORIGINALS_PATH = "/photoprism-media/Library"
    PHOTOPRISM_IMPORT_PATH    = "/photoprism-media/Import"
    PHOTOPRISM_STORAGE_PATH   = "/photoprism-storage" # Storage PATH for generated files like cache and thumbnails
    # Unix permissions
    PHOTOPRISM_UID   = 500
    PHOTOPRISM_GID   = 100
    PHOTOPRISM_UMASK = 0000
  }

  templates = [
    {
      data        = <<EOF
      {{ with nomadVar "nomad/jobs/photoprism" -}}
      PHOTOPRISM_ADMIN_USER={{ .admin_user }}
      PHOTOPRISM_ADMIN_PASSWORD={{ .admin_password }}
      PHOTOPRISM_DATABASE_DRIVER=mysql
      PHOTOPRISM_DATABASE_NAME={{ .db_name }}
      PHOTOPRISM_DATABASE_USER={{ .db_user }}
      PHOTOPRISM_DATABASE_PASSWORD={{ .db_pass }}
      PHOTOPRISM_DATABASE_SERVER=127.0.0.1:3306
      {{- end }}
      {{ if eq (env "meta.hw_transcode.type") "raspberry" -}}
      PHOTOPRISM_FFMPEG_ENCODER=raspberry
      PHOTOPRISM_FFMPEG_BUFFERS=64
      {{ else if eq (env "meta.hw_transcode.type") "intel" -}}
      PHOTOPRISM_FFMPEG_ENCODER=intel
      PHOTOPRISM_INIT="intel tensorflow"
      {{- end }}
      EOF
      dest_prefix = "$${NOMAD_SECRETS_DIR}/"
      dest        = "env"
      env         = true
      mount       = false
    },
  ]
}