homelab-nomad/databases/mysql.nomad

job "mysql-server" {
  datacenters = ["dc1"]
  type = "service"
  priority = 80

  group "mysql-server" {
    count = 1

    restart {
      attempts = 10
      interval = "5m"
      delay = "25s"
      mode = "delay"
    }

    network {
      mode = "bridge"

      port "db" {
        to = 3306
        host_network = "wesher"
      }

      port "tls" {
        host_network = "wesher"
      }
    }

    volume "mysql-data" {
      type = "host"
      read_only = false
      source = "mysql-data"
    }

    service {
      name = "mysql-server"
      provider = "nomad"
      port = "db"
    }

    service {
      name = "mysql-tls"
      provider = "nomad"
      port = "tls"
    }

    task "mysql-server" {
      driver = "docker"

      config {
        image = "mariadb:10"
        ports = ["db"]
        args = ["--innodb-buffer-pool-size=1G"]
      }

      volume_mount {
        volume = "mysql-data"
        destination = "/var/lib/mysql"
        read_only = false
      }

      env = {
        # Allow connections from any host
        "MYSQL_ROOT_HOST" = "%"
      }

      template {
        data = <<EOH
{{ with nomadVar "nomad/jobs/mysql-server" }}
MYSQL_ROOT_PASSWORD={{ .mysql_root_password }}
{{ end }}
        EOH
        destination = "secrets/db.env"
        env = true
      }

      resources {
        cpu = 300
        memory = 1024
      }
    }

    task "stunnel" {
      driver = "docker"

      config {
        image = "alpine:3.17"
        ports = ["tls"]
        args = ["/bin/sh", "${NOMAD_TASK_DIR}/start.sh"]
      }

      resources {
        cpu = 100
        memory = 100
      }

      template {
        data = <<EOF
set -e
apk add stunnel
exec stunnel ${NOMAD_TASK_DIR}/stunnel.conf
        EOF
        destination = "${NOMAD_TASK_DIR}/start.sh"
      }

      template {
        data = <<EOF
syslog = no
foreground = yes
delay = yes

[mysql_server]

accept = {{ env "NOMAD_PORT_tls" }}
connect = 127.0.0.1:3306
ciphers = PSK
PSKsecrets = {{ env "NOMAD_SECRETS_DIR" }}/stunnel_psk.txt
        EOF
        destination = "${NOMAD_TASK_DIR}/stunnel.conf"
      }

      template {
        data = <<EOF
{{ with nomadVar "nomad/jobs/mysql-server" -}}
{{ .allowed_psks }}
{{- end }}
        EOF
        destination = "${NOMAD_SECRETS_DIR}/stunnel_psk.txt"
      }
    }
  }
}